[sisyphus] Re: sedna package (дубль 2)

[Michael Shigorin]

On Mon, May 23, 2005 at 06:44:19PM +0400, Andrey Fomichev wrote:
> > > %_libdir/libsedna.a
> > Это лучше в отдельный субпакет (в идеале -- devel-static)
> > > %_includedir/libsedna.h
> > > %_datadir/%name-%version/examples
> > Это лучше в отдельный субпакет (devel)
> А можно я все драйверы положу в sedna-devel?

Эээ... если они могут быть (бес)полезны отдельно, конфликтовать
или ещё как -- то может иметь смысл sedna-drivers или даже
sedna-driver-*, но если они по версиям и надобности синхронны 
с основным пакетом -- отколупывать незачем.

Если заметили, строчку между .h и examples я убрал из цитаты.

> И devel-static мне не очень хочется. Ну зачем так много
> пакетов, неудобно же будет. Я думаю, sedna-devel и так
> будет занимать копейки (явно <100Kb).

Ну в него *.a тогда.

> А некоторые примеры, кстати, относятся к драйверам (т.е. для
> разработки), а некоторые просто для того, чтобы Седну
> попробовать, т.е. данные + запросы на XQuery. Думаю их надо
> оставить в sedna, а примеры, относящиеся к драйверам, положить
> в sedna-devel.

Примеры обычно лучше в doc или devel всё же, но дело Ваше.
Тут уже рекомендации со вкусовщиной пошли, а не критические. :)

> > > %changelog
> > > * Mon May 23 2005 Andrey Fomichev <fomichev на ispras.ru>
> > В конце хорошо бы версию ("0.5.6-alt1") -- неплохо добавляет
> > add_changelog из пакета sisyphus (+к нему есть vim macro).
> Удобно. А как пользоваться?

Чем -- add_changelog?  Напустить на spec.  Макросом?
Положить аттач в ~/.vim/ftplugin, звать \ac.

-- 
 ---- WBR, Michael Shigorin <mike на altlinux.ru>
  ------ Linux.Kiev http://www.linux.kiev.ua/
----------- следующая часть -----------
" Plugin to update the %changelog section of RPM spec files
" This is a combination of ideas and code from
" spec.vim by Gustavo Niemeyer <niemeyer на conectiva.com>
" spec_ftplugin.vim by Guillaume Rousse <rousse на ccr.jussieu.fr>
" and Sir Raorn <raorn на altlinux.ru>
" add_changelog utility by Dmitry V. Levin <ldv на altlinux.ru>
" Filename: spec_alt.vim
" Version: 0.0.1

if exists("b:did_altchangelog_ftplugin") | finish | endif

let b:did_altchangelog_ftplugin = 1

if !exists("no_plugin_maps") && !exists("no_spec_maps")
	if !hasmapto("<Plug>SpecAltChangelog")
		map <buffer> <LocalLeader>ac <Plug>SpecAltChangelog
	endif
endif

noremap <buffer> <unique> <script> <Plug>SpecAltChangelog :call <SID>SpecAltChangelog()<CR>

" Useful settings
setlocal makeprg=rpm\ -ba\ %
setlocal errorformat=error:\ line\ %l:\ %m
 
" Helper functions
function <SID>Date()
    let savelang = v:lc_time
    execute "language time C"
    let date = strftime("%a %b %d %Y")
    execute "language time " . savelang
    return date
endfunction

if !exists("*s:GetFirstLocation")
        " Return location of first line matching
	" the given pattern after the given line
        " Return -1 if not found at the end of the file
        function s:GetFirstLocation(from, pattern)
                let linenb = a:from
                while (linenb <= line("$"))
                        let linenb = linenb + 1
                        let linestr = getline(linenb)
                        if (linestr =~ a:pattern)
                                return linenb
                        endif
                endwhile
                return -1
        endfunction
endif

" Main function
if !exists("*s:SpecAltChangelog")
	function s:SpecAltChangelog()
		let line = 0
		let packager = system("rpm --eval %packager")
		" get rid of this !#&* trailing <NL>
		let packager = strpart(packager, 0, strlen(packager)-1)
		if packager == "%packager"
		          echomsg "Configuration error: undefined packager"
			  " Correct? Really exit?
			  exit
		endif
		let date = <SID>Date()
		let svr = system("rpm -q --qf '%|SERIAL?{%{SERIAL}:}|%{VERSION}-%{RELEASE}\n' --specfile ".expand("%")." |head -1")
		let svr = strpart(svr, 0, strlen(svr)-1)
		let full = "* ".date." ".packager." ".svr
		let chgline = <SID>GetFirstLocation(0, '^%changelog')
		if (chgline == -1)
			let option = confirm("Can't find %changelog. Create one? ","&End of file\n&Here\n&Cancel",3)
			if (option == 1)
				call append(line("$"),"")
				call append(line("$"),"%changelog")
				execute line("$")
				let chgline = line(".")
			elseif (option == 2)
				call append(line("."),"%changelog")
				normal j
				let chgline = line(".")
			endif
		endif
		if (chgline != -1)
			let insert_line = 0
			" TODO
			" echo "$spec: version \"$oldver\" unchanged, skipping"
			" like add_changelog do this
			" 
			" empty line just after chgline may break this
			" 
			" Really compare whole line, or only packager+svr?
			" The best variant - do this configurable
			if (getline(chgline+1) != full)
				call append(chgline, full)
				call append(chgline+1,"- ")
				call append(chgline+2,"")
				let insert_line = chgline+2
			else
				let line = chgline
				if !exists("g:spec_chglog_prepend")
					while !(getline(line+2) =~ '^\( *\|\*.*\)$')
						let line = line+1
					endwhile
				endif
				call append(line+1,"- ")
				let insert_line = line+2
			endif
			execute insert_line
			startinsert!
		endif
	endfunction
endif